build.gradle

plugins {
  id "application"
  id "com.diffplug.spotless" version "${spotlessVersion}"
  id "com.github.johnrengelman.shadow" version "${shadowVersion}"
  id "com.github.node-gradle.node" version "${nodeVersion}"
  id "com.github.spotbugs" version "${spotbugsVersion}"
  id "com.star-zero.gradle.githook" version "${githooksVersion}"
  id "eclipse-wtp"
  id "io.micronaut.application" version "${mnPluginVersion}"
  id "jacoco"
  id "java-library"
  id "maven-publish"
}

sourceCompatibility = JavaVersion.VERSION_11
compileJava.options.encoding = "UTF-8"

mainClassName = "gov.usgs.earthquake.nshmp.www.Application"

configurations {
  nshmp
}

java {
  withSourcesJar()
}

ext {
  libsDir = "libs"
  nshmpLib = "${libsDir}/nshmp-lib-artifacts"
  nshmpLibGradleDir = "${nshmpLib}/gradle"
  spotbugsDir = "${nshmpLib}/gradle"
  spotlessDir = "${nshmpLib}/src/main/resources"
}

apply from: "${projectDir}/gradle/repositories.gradle"
apply from: "${projectDir}/gradle/dependencies.gradle"

test {
  useJUnitPlatform()

  reports {
    junitXml.enabled = true
    html.enabled = true
  }
}

jacocoTestReport {
  reports {
    xml.enabled true
    html.enabled true
  }
}
check.dependsOn jacocoTestReport

shadowJar {
  mergeServiceFiles()
}

tasks.withType(JavaCompile) {
  options.encoding = "UTF-8"
  options.compilerArgs.add("-parameters")
}

tasks.withType(JavaExec) {
  jvmArgs('-noverify', '-XX:TieredStopAtLevel=1', '-Dcom.sun.management.jmxremote')
}

task libsClean(type: Delete) {
  delete libsDir
}
clean.dependsOn libsClean


/* Add HTML reports to SpotBugs */
tasks.withType(com.github.spotbugs.snom.SpotBugsTask) {
  reports {
    html {
      enabled true
      stylesheet = 'fancy-hist.xsl'
    }
  }
}

gradle.afterProject {
  copy {
    from {
      configurations.nshmp.collect { zipTree(it) }
    }
    into nshmpLib
  }
  apply from: "${nshmpLibGradleDir}/git-hooks.gradle"
  // apply from: "${nshmpLibGradleDir}/node.gradle"
  apply from: "${nshmpLibGradleDir}/spotbugs.gradle"
  apply from: "${nshmpLibGradleDir}/spotless.gradle"
  apply from: "${projectDir}/gradle/node.gradle"
}